Содержание


В первую очередь – рекомендую настроить на касты по наведению мыши (mouseover) через стандартный интерфейс. Это позволит кастовать все заклинания без выбора цели, что особенно удобно для Огненного шока и Пронизывающего ветра, но я это использую для всех заклинаний:

Все специализации

  • Использовать одновременно Хождение по воде (без ГКД) и призыв случайного избранного маунта: 
    #showtooltip Яростная буря предсказателя
/cast [nomounted,nocombat] Хождение по воде
/run C_MountJournal.SummonByID(0)
  • Универсальный маусовер макрос для атакующих заклинаний. Если у вас есть противник под курсором – кинет в него, иначе в вашу цель. Удобно развешивать Огненный шок не меняя текущей цели. Можно использовать для таких заклинаний, как Молния, Выброс лавы, Развеивание магии и других: 
    #showtooltip  
/cast [@mouseover,harm,exists,nodead][] Огненный шок
  • Маусовер макрос, который позволяет назначить на одну кнопку два действия – для врага и для союзника. Можно использовать на Развеивание магии и Очищение духа: 
    #showtooltip 
/use [@mouseover,nodead,harm] Развеивание магии;[@mouseover,nodead,help] Очищение духа;[@target,nodead,harm] Развеивание магии;[@target,nodead,help][@player] Очищение духа
  • Макрос, ограничивающий автоматический выбор таргета в случае нажатия без выбранной цели или маусовера: 
    #showtooltip  
/cast [@mouseover,harm,exists,nodead][@target] Огненный шок
  • Маусовер макрос для лечащих заклинаний. Можно использовать для таких заклинаний, как Исцеляющий всплеск, Очищение духа и других: 
    #showtooltip 
/cast [@mouseover,noharm,exists] [@target,noharm,exists] [@player] Исцеляющий всплеск

Важно! Данный приоритет выбора цели (маусовер → цель → игрок) можно реализовать через стандартный интерфейс, без необходимости использовать макрос. Для этого в параметрах игры, в разделе Бой поставьте галочку около «Применение заклинания по наведению мыши» и выберите клавишу «Нет».

  • Отмена активного элементаля, со взятым талантом Повелитель изначальных стихий. Альтернативный вариант – щелкнуть правой кнопкой мыши по портрету элементаля и выбрать «Отпустить»: 
    /petdismiss
  • Накладывание дебаффа по фокусу, а если фокус отсутствует – по фрейму босса. Полезно на энкаунтерах, где нужно поддерживать Огненный шок на 2 целях, атакуя по приоритету одну из них: 
    #showtooltip 
/cast [@focus,exists,nodead,harm] [@boss1,exists,nodead,harm] Огненный шок
  • Сбивание каста по фокусу. Можно также использовать предыдущий макрос, заменив Огненный шок на Пронизывающий ветер: 
    #showtooltip 
/cast [@focus] Пронизывающий ветер
  • Сбивание каста по фокусу, если фокуса нет, то сбивает цели под маусовером. Если там нет врага, то сбивает текущей цели: 
    #showtooltip
/cast [@focus,exists,harm,nodead][@mouseover,harm,exists,nodead][] Пронизывающий ветер
  • Этот макрос позволяет кинуть Огненный шок на соседнюю цель, не меняя вашей текущей. Выбирается ближайшая к вам цель, в сторону которой направлена камера: 
    #showtooltip  
/targetenemy  
/cast Огненный шок  
/targetlasttarget
  • Применяет Тотем ветряного порыва прямо прямо под вашего персонажа, позволяя сразу получить бонус скорости и не терять времени на установку тотема: 
    #showtooltip
/cast [@player] Тотем ветряного порыва
  • Применяет Тотем конденсации прямо под курсор, без предварительного выбора цели: 
    #showtooltip
/cast [@cursor] Тотем конденсации
  • Позволяет вынести Реинкарнация на панель заклинаний чтобы следить за временем восстановления: 
    #showtooltip Реинкарнация
  • Вне боя использует Дух предков (для Рестора замените на Древнее видение), а в бою – инженерский батл-рес. 
    #showtooltip
/use [combat] Сносно работающий кабельный дефибриллятор; [nocombat] Дух предков
  • Использование недолговечных зелий из котла, если они есть, а затем обычных зелий из сумки: 
    #showtooltip
/use item:245898
/use item:245897
/use item:245903
/use item:245902
/use item:241308
/use item:241309
/use item:241288
/use item:241289

Стихии

  • Все баффы на одной кнопке: 
    #showtooltip
/castsequence [@player] reset=3 Небесная ярость, Щит молний
  • Данный макрос позволяет кастовать Землетрясение сразу на место под курсором, избавляя от лишнего клика мышкой: 
    #showtooltip
/cast [@cursor] Землетрясение
  • Макрос на Перерождение: 
    #showtooltip Перерождение
/use 13
/cast Перерождение
/cast Берсерк
/cast Стремительность предков
/cast Природная стремительность

Совершенствование

  • Все баффы на одной кнопке: 
    #showtooltip
/castsequence [@player] reset=3 Небесная ярость, Щит молний

Исцеление

  • Все баффы на одной кнопке: 
    #showtooltip
/castsequence [@player] reset=3 Небесная ярость, Водный щит
  • Природная стремительность и Цепное исцеление на одной кнопке: 
    #showtooltip Цепное исцеление
/cast Природная стремительность
/cast Стремительность предков
/cast [@mouseover,help,exists,nodead][] Цепное исцеление

Универсальные и полезные макросы

  • Способности через модификатор: 
    #showtooltip
/use [mod:ctrl] умение 4;[mod:alt] умение 3;[mod:shift] умение 2;умение 1

    #showtooltip
/use [mod:shift] Цепное исцеление; Цепная молния

Одна из самых популярных разновидностей макросов. По сути – просто сокращается количество использованных кнопок на панелях заклинаний. Скрытые панели решают эту проблему.

  • Основной макрос для взятия цели в фокус. Первое нажатие берет в фокус цель под маусовером или в таргете. Если нажать без маусовера или таргета, то очищает фокус: 
    /focus [target=mouseover,exists][exists]
/stopmacro [target=mouseover,exists][exists]
/clearfocus
  • Аналогичный макрос, но дополнительно ставит метку на фокус, если на нем до этого не было метки. Цифра 7 отвечает за метку, в данном случае крест: 
    /focus [target=mouseover,exists][exists]
/tm [@focus] 7
/stopmacro [target=mouseover,exists][exists]
/clearfocus
  • Ставит на землю метку «Череп». Меняйте цифру на конце макроса для других меток: 
    /wm [@cursor] 8
  • Стереть все метки, поставленные на землю: 
    /click CompactRaidFrameManagerDisplayFrameLeaderOptionsRaidWorldMarkerButton
/click DropDownList1Button9
  • Использование активных (прожимных) Аксессуаров с панели заклинаний: 
    #showtooltip
/use 13

    #showtooltip
/use 14
  • Использование способности на поясе у инженеров: 
    #showtooltip
/use 6
  • Использование инженерского планера: 
    #showtooltip
/cancelaura Нитроускорители
/use 15

Модификаторы цели

Символ «@» равносилен «target=».

  • @player – нацеливается на игрока.
  • @target – нацеливается на текущую цель игрока.
  • @targettarget – нацеливается на цель цели. Например, при использовании цели на босса, она будет нацелена на танка. Данный модификатор можно стакать, выбирая цель цели цели цели цели и т.д.
  • @mouseover – нацеливает заклинание на цель, над которой в данный момент находится курсор мыши.
  • @cursor – использование заклинаний по области, в то место, на котором в данный момент находится курсор (доступно только для заклинаний с применением на область, например Землетрясение или Целительный ливень).
  • @focus – нацеливается на цель у вас в фокусе.
  • @boss1 – нацеливается на первого босса в списке боссов. Обычно доступно только в подземельях и рейдах.
  • @arena1 – нацеливается на первого человека в списке Арены. Это модификатор только для PvP, обычно доступный только во время боев на арене. Есть еще варианты, такие как arena2, arena3 и т. д.
  • @pet – нацеливается на питомца игрока.

Условия

Условные выражения используются для определения возможности действия. Чтобы они вели себя противоположным образом, добавьте «no» перед условным выражением. Например, noharm верно для любой цели, которая не является врагом, но может включать например нейтральных NPC, а nocombat верно если вы не находитесь в бою.

Полный список условий:

  • pet – верно, если у игрока в данный момент есть питомец.
  • combat – верно, если вы в бою.
  • harm – верно, если целью для использования способности является враг.
  • help – верно, если целью для использования способности является союзник.
  • dead – верно, если цель для использования способности мертва.
  • exists – верно, если цель для использования способности существует.
  • channeling – верно, если вы в данный момент используете потоковое заклинание.
  • button:number – (или btn) используется для проверки, с помощью какой кнопки мыши вы активировали макрос. [button:1] по умолчанию, левая кнопка, [button:2] правая, [кнопка:3] средняя. Для мышей с большим количеством кнопок количество кнопок соответствует шаблону для опции.
  • known:ID или название заклинания – верно, если у вас выучен талант или известно заклинание.
  • noknown::ID или название заклинания – верно, если у вас не выучен талант или неизвестно заклинание.
  • equipped:slot – (или надето) верно, если в слоте есть предмет. Например, [equipped:chest] будет верным, если на вас надета нагрудная броня.
  • spec:number – верно, если вы в настоящее время находитесь в специализации, заданной числом. Специализации отсортированы в алфавитном порядке и могут быть проверены в меню специализаций.
  • group – верно, если вы в данный момент находитесь в группе. Может быть перестроен в [group:party] или [group:raid].
  • indoors – верно, если вы в настоящее время находитесь в локации, которая считается «закрытой», например помещением.
  • outdoors – верно, если вы в настоящее время находитесь в локации, которая считается на «открытой», под открытым небом.
  • flyable – верно, если вы в данный момент можете летать.
  • mounted – верно, если вы в настоящее время на средстве передвижения.
  • fly – верно, если вы в данный момент летите.
  • swimming – верно, если вы в данный момент плаваете.

Модификаторы комбинаций клавиш

  • mod:shift – верно, если комбинация клавиш была нажата при нажатой клавише SHIFT.
  • mod:alt – верно, если комбинация клавиш была нажата при нажатой клавише ALT.
  • mod:ctrl – верно, если комбинация клавиш была нажата при нажатой клавише CTRL.